int GOAL = 2016;       //ゴール
int CUBE_NUM_0 = 100;  //障害物の数の初期値
int CUBE_SIZE  = 30;   //障害物の大きさ
int X  = 600/2;        //自機のx座標
int Y  = 600-40;       //自機のy座標
int VX = 3;            //自機の速度x成分
int VY = 5;            //自機の速度y成分

int a = 0;
ArrayList cubes;     //障害物
int numberOfCubes;   //障害物の数
int distance;        //進んだ距離
int reachedDistance; //進められた距離
int time;            //経過時間
boolean alive;       //ゲーム進行状態
boolean gameover;    //ゲームオーバー状態
boolean gameclear;   //ゲームクリア状態
//PFont font;       //文字の書体

void setup() {
  size(600, 600, P3D);
  frameRate(60);
  smooth();
  //font = loadFont("CenturyGothic.ttf");
  setupGame();
}

//ゲームの初期化
void setupGame() {
  a = 0;
  frameCount = 0;
  distance = 0;
  alive = true;
  gameover = false;
  gameclear = false;
  numberOfCubes = CUBE_NUM_0;
  cubes = new ArrayList();
  for (int i = 0; i<numberOfCubes; i++)
    cubes.add( new Cube() );
}

void draw() {
  background(255);
  showText();
  translate(0, height*7/12, -height*5/6);
  rotateX(PI*5/12);
  stroke(0);
  pointLight(200, 200, 200, X-10, Y, 60);
  if (gameover)  pointLight(255, 0, 0, X-10, Y, 60);
  if (gameclear) pointLight(0, 0, 255, X-10, Y, 60);
  for (int i = 0; i<numberOfCubes; i++) {
    Cube cube = (Cube) cubes.get(i);
    cube.show();
    cube.move();
    if (!gameclear) cube.collition();
  }
  if (gameover) {
    gameOver();
  } else if (gameclear) {
    gameClear();
  } else if (alive) {
    time = frameCount/60;
    numberOfCubes = 100 + (int)distance/100;
    distance += VY;
    if (mouseButton == CENTER) distance += VY*3;
    reachedDistance = distance;
    showShip();
  }
  updateCubes();
  if (distance >= GOAL*10) { 
    gameclear = true;
    reachedDistance = GOAL*10;
  }
}

//障害物のクラス外部からの処理
void updateCubes() {
  //障害物の数を更新
  if (cubes.size()<numberOfCubes) {
    cubes.add( new Cube() );
  }
  //通り過ぎた障害物を前に移動
  for (int i = 0; i<numberOfCubes; i++) {
    Cube cube = (Cube) cubes.get(i);
    if (Y+10 < cube.y) {
      cube.x = (int)random(X-width*1.5, X+width*1.5);
      cube.y = (int)random(Y-height*2, Y-height*1 );
      cube.d = CUBE_SIZE;
    }
  }
}

//ゲームオーバー時の表示
void gameOver() {
  pushMatrix();
  translate(X-width/2, Y-height+20, 0);
  rotateX(PI*3/2);
  //textFont(font, 100);
  textSize(100);
  textAlign(CENTER, CENTER);
  fill(0);
  text("GAME OVER", width/2, -height/2);
  //textFont(font, 30);
  textSize(30);
  text("PRESS ANY KEY TO RESTART.", width/2, -height/2+100);
  popMatrix();
  //リスタート
  if (keyPressed) setupGame();
}

//ゲームクリア時の表示
void gameClear() {
  pushMatrix();
  translate(X-width/2, Y-height+20, 0);
  rotateX(PI*3/2);
  //textFont(font, 100);
  textSize(100);
  textAlign(CENTER, CENTER);
  fill(0);
  text("HAPPY NEW YEAR!", width/2, -height/2);
  //textFont(font, 30);
  textSize(30);
  text("PRESS ANY KEY TO RESTART.", width/2, -height/2+100);
  popMatrix();
  //リスタート
  if (keyPressed) setupGame();
}

//他の文字列の描画
void showText() {
  //pushMatrix();
  //translate(X-width/2, Y-height+20, 0);
  //rotateX(PI*3/2);
  //translate(0, -height, 0);
  //textFont(font, 50);
  textSize(50);
  fill(0);
  //text("CUBES: "+(int)numberOfCubes, 0, 200);
  //text("TIME: "+(int)time, width, 200);
  //textFont(font, 100);
  textSize(100);
  textAlign(CENTER, CENTER);
  noFill();
  stroke(0);
  if (a<int(reachedDistance/10) && alive && !gameclear)
    a+=2;
  text(a, width/2, height/10);
  //popMatrix();
}








//自機の描画
void showShip() {
  stroke(255);
  fill(255, 0, 0);
  beginShape();
  //右の面
  vertex(X-10, Y+20, 0 );
  vertex(X+10, Y+20, 0);
  vertex(X, Y+16, 5);
  //左の面
  vertex(X, Y, 0);
  vertex(X-10, Y+20, 0 );
  vertex(X, Y+16, 5);
  //後ろの面
  vertex(X, Y, 0);
  vertex(X+10, Y+20, 0);
  vertex(X, Y+16, 5);
  endShape();
}

boolean tooClose(float x, float y, float X, float Y) {
  return sqrt(sq(x-X)+sq(y-Y))<=300;
}

class Cube {
  int x, y, d;

  Cube() {
    //開始時に自機と障害物を離す
    do {
      x = (int)random(-width, width);
      y = (int)random(height);
    } while (tooClose(x, y, X, Y));
    d = CUBE_SIZE;
  }

  void show() {
    pushMatrix();
    translate(x+d/2, y+d/2, 0);
    noStroke();
    fill(255);
    box(d, d, d);
    popMatrix();
  }

  void collition() {
    if (thisCubeGotHit() && alive) {
      alive = false;
      gameover = true;
    }
  }

  void move() {
    if (mousePressed && !gameover) {
      if (mouseButton == RIGHT)  x -= VX;
      if (mouseButton == LEFT)   x += VX;
      if (mouseButton == CENTER) y += VY*3;
    }
    y += VY;
  }
  boolean thisCubeGotHit() {
    return (x<X&&X<x+d)&&(y<Y&&Y<y+d);
  }
}