int[][] BitMap={
  //◆◆◆ここに自分のビットマップを貼ってください。◆◆◆
  {0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}, 
  {0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}, 
  {0, 0, 0, 0, 0, 0, 1, 1, 1, 1, 1, 1, 0, 0, 0, 0}, 
  {0, 0, 0, 0, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 0, 0}, 
  {0, 0, 0, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 0, 0}, 
  {0, 0, 1, 1, 1, 1, 0, 0, 0, 0, 0, 1, 1, 1, 1, 0}, 
  {0, 0, 1, 1, 1, 0, 0, 0, 0, 0, 0, 1, 1, 1, 1, 0}, 
  {0, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 0, 0}, 
  {0, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 0, 0, 0}, 
  {0, 1, 1, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}, 
  {0, 1, 1, 1, 1, 0, 0, 0, 0, 0, 1, 1, 1, 0, 0, 0}, 
  {0, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 0, 0, 0}, 
  {0, 0, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 0, 0, 0, 0}, 
  {0, 0, 0, 0, 0, 1, 1, 1, 1, 0, 0, 0, 0, 0, 0, 0}, 
  {0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}, 
  {0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}
};


int  B[][][]={
  //◆◆◆ 自分の文字に必要な点の数に変えます ◆◆◆
  { {13, 284/*これは...*/}, {85, -86}, {489, 55}, {456, 183} }, 
  { {456, 183}, {450, 241}, {413, 271}, {344, 273} }, 
  { {344, 273}, {296, 271}, {181, 273}, {112, 272} }, 
  { {112, 272}, {97, 330}, {221, 381}, {304, 315} }, 
  { {304, 315}, {377, 280}, {431, 331}, {383, 370} }, 
  { {383, 370}, {272, 461}, {4, 447}, {13, 284/*これと同じにする*/} }, 
};


//以下はいじらないで結構です
void setup() {
  size(1024, 800);
  background(0);
  for (int i = 0; i<B.length; i++) {
    selected[i][0]=false;
    selected[i][1]=false;
    rectselected[i]=false;
  }
}
void draw() {
  translate(256, 144);
  background(50);
  drawBitmap();
  Bezier(B);
  mainTool();
}
//ここをいじる必要はありません

boolean[][] selected = new boolean[B.length][2];
boolean[] rectselected = new boolean[B.length];
int[][][] p;
boolean t_was_pressed = false;
int count;
int counter2;
void drawBitmap() {
  for (int j=0; j<16; j++) {
    for (int i=0; i<16; i++) {
      if (BitMap[j][i] ==0) { 
        v_pixel(32, i, j, 0, 0, 0);
      } else
      { 
        v_pixel(32, i, j, 100, 100, 100);
      }
    }
  }
}
void Bezier(int c[][][]) {
  p=new int[21][2][2];
  for (int i =0; i<B.length; i++) {
    polygonize( c[i], p);
    polygonmodel(p, 21);
  }
}

void polygonize(int c[][], int p[][][])
{
  float t;
  int i;
  for (t=0, i=0; t<1; t=t+0.05, i++) {
    Bezier_point(c, t, p[i][0]);
    Bezier_point(c, t+0.05, p[i][1]);
  }
}

void Bezier_point( int c[][], float t, int p[]) {
  float t1;
  t1=1-t;
  p[0]=int( t1*t1*t1*c[0][0]+3*t*t1*t1*c[1][0]+3*t*t*t1*c[2][0]+t*t*t*c[3][0] );  // x座標の計算
  p[1]=int( t1*t1*t1*c[0][1]+3*t*t1*t1*c[1][1]+3*t*t*t1*c[2][1]+t*t*t*c[3][1] );  // Y座標の計算
}

void polygonmodel(int p[][][], int num)
{
  for (int i =0; i<num; i++) {
    Bresen(p[i][0][0], p[i][0][1], p[i][1][0], p[i][1][1]);
  }
}
void Bresen(int xs, int ys, int xe, int ye)
{
  int w, er, x, y;
  if (abs(xe-xs)>abs(ye-ys)) {
    //  reverting (ys, ye) with (xs, xe)
    if (xs>xe) {
      w=xs; 
      xs=xe; 
      xe=w;
      w=ys; 
      ys=ye; 
      ye=w;
    }
    y=ys; 
    er=(xe-xs);
    for ( x=xs; x<=xe; x++) {
      v_pixel(1, x, y, 255, 255, 255);
      er=er+abs(ye-ys)*2;
      if ( er >=(xe-xs)*2) {
        if (ys<ye)
          y = y+1;
        else
          y = y-1;
        er = er-(xe-xs)*2;
      }
    }
  } else {
    //  reverting (ys, ye) with (xs, xe)
    if (ys>ye) {
      w=ys; 
      ys=ye; 
      ye=w;
      w=xs; 
      xs=xe; 
      xe=w;
    }
    x=xs; 
    er=(ye-ys);
    for ( y=ys; y<=ye; y++) {
      v_pixel(1, x, y, 255, 255, 255);
      er=er+abs(xe-xs)*2;
      if ( er >=(ye-ys)*2) {
        if (xs<xe)
          x = x+1;
        else
          x = x-1;
        er = er-(ye-ys)*2;
      }
    }
  }
}
void keyPressed() {
  if ( key== 's' ) {
    saveFrame("Result.jpg");
  }
}
void v_pixel(int n, int x, int y, int r, int g, int b)
{
  if (n==1)
  {
    stroke(color(r, g, b));
    point(x, y);
  } else
  {
    fill(r, g, b);
    noStroke();
    rect(x*n, y*n, n, n);
  }
}
void mainTool() {
  int n = B.length;
  int[][][] tempB = new int[n][4][2];
  for (int a=0; a<n; a++) {
    for (int b=0; b<4; b++) {
      tempB[a][b][0] = B[a][b][0];
      tempB[a][b][1] = B[a][b][1];
    }
  }
  //点の重複操作の防止
  boolean alone = true;
  for (int k=0; k<B.length; k++) {
    if (selected[k][0] || selected[k][1] || rectselected[k])
      alone =false;
  }
  //GUI
  float dist = sqrt(sq(mouseX-256-10)+sq(mouseY-144-10));
  if (dist<=10) fill(255); 
  else fill(0);
  ellipse(10, 10, 20, 20);
  if (dist<=10) fill(0); 
  else fill(255);
  text("+", 2.5, 16);
  //新しい点の追加
  counter2++;
  if (mousePressed && dist<=10 && alone && counter2>20) {
    counter2=0;
    B = new int[n+1][4][2];
    for (int a=0; a<n; a++) {
      for (int b=0; b<4; b++) {
        B[a][b][0] = tempB[a][b][0]; 
        B[a][b][1] = tempB[a][b][1];
      }
    }
    B[n][0][0] = (B[n-1][0][0]+B[n-1][3][0])/2;
    B[n][0][1] = (B[n-1][0][1]+B[n-1][3][1])/2;
    B[n][3][0] = tempB[0][0][0];
    B[n][3][1] = tempB[0][0][1];

    B[n-1][3][0] = B[n][0][0];
    B[n-1][3][1] = B[n][0][1];
    B[n-1][2][0] = (B[n][0][0]+B[n-1][0][0])/2;
    B[n-1][2][1] = (B[n][0][1]+B[n-1][0][1])/2;

    B[n][2][0] = tempB[n-1][2][0];
    B[n][2][1] = tempB[n-1][2][1];
    B[n][1][0] = (B[n][3][0]+B[n][0][0])/2;
    B[n][1][1] = (B[n][3][1]+B[n][0][1])/2;

    //初期化
    selected = new boolean[B.length][2];
    rectselected = new boolean[B.length];
    for (int i = 0; i<B.length; i++) {
      selected[i][0] = false;
      selected[i][1] = false;
      rectselected[i] = false;
    }
  }
  for (int i = 0; i<B.length; i++) {

    //線の位置更新
    for (int j = 0; j<2; j++) {
      float[] distance = new float[2];
      distance[j] = sqrt(sq(B[i][j+1][0]-mouseX+256)+sq(B[i][j+1][1]-mouseY+144));
      if (distance[j]<=5 && mousePressed && alone) selected[i][j] = true;
      if (!mousePressed) selected[i][j]=false;
      if (selected[i][j]) {
        B[i][j+1][0]= mouseX-256;
        B[i][j+1][1]= mouseY-144;
      }
    }
    //点の位置更新
    float rectdistance = sqrt(sq(B[i][0][0]-mouseX+256)+sq(B[i][0][1]-mouseY+144));
    if (rectdistance<=5 && mousePressed && alone) rectselected[i] = true;
    if (!mousePressed) rectselected[i] = false;
    if (rectselected[i]) {
      B[i][0][0]= mouseX-256;
      B[i][0][1]= mouseY-144;
      B[i][1][0]=tempB[i][1][0]+(mouseX-pmouseX);
      B[i][1][1]=tempB[i][1][1]+(mouseY-pmouseY);
      int tempi = i;
      if (i-1<0) i=B.length;
      B[i-1][3][0]= mouseX-256;
      B[i-1][3][1]= mouseY-144;
      B[i-1][2][0]=tempB[i-1][2][0]+(mouseX-pmouseX);
      B[i-1][2][1]=tempB[i-1][2][1]+(mouseY-pmouseY);
      i = tempi;
      //点移動時の線移動
    }

    //線と点の描画
    noFill();
    stroke(0, 255, 0);
    line(B[i][0][0], B[i][0][1], B[i][1][0], B[i][1][1]);
    ellipse(B[i][1][0], B[i][1][1], 10, 10);
    stroke(0, 255, 255);
    line(B[i][3][0], B[i][3][1], B[i][2][0], B[i][2][1]);
    ellipse(B[i][2][0], B[i][2][1], 10, 10);
    stroke(255);
    rectMode(CENTER);
    rect(B[i][0][0], B[i][0][1], 10, 10);
    rect(B[i][3][0], B[i][3][1], 10, 10);
  }
  //ファイルの生成
  if (keyPressed && key=='t') {
    t_was_pressed = true;
    count=0;
  }
  //文字の描画
  textSize(20);
  fill(255);
  text("press T key to save", 0, -30);
  text("NOTE: your changes will be saved in hamazon.txt", 0, 522); 
  fill(0, 255, 55);
  if (t_was_pressed) {
    text("SAVED", 420, -30);
  }
  count++;
  if (count>50)t_was_pressed=false;
}